#! /usr/bin/mawk -f
BEGIN { 

ID    =    "dclpsline 1.0"
DATE  =                               "95/03/19(numaguti)" 

EX    =    "change values for setlinecap, setlinejoin and setmiterlimit"

USAGE =  "% dclpsline [lc=<0,1,2,b,r,p] [lj=<0,1,2,m,r,b>] [ml=<num>] <file>"

#----------------------------------------------------------------------------
# OPTIONS

    lc=0; q["lc"]="0|b: butt cap,   1|r: round cap,  2|p: proj. square cap [0]"
    lj=0; q["lj"]="0|m: miter join, 1|r: round join, 2|b: bevel join [0]"
    ml=10; q["ml"]="miterlimit for lj=0|m [10]"

    if (ARGV[1] == "-help" || ARGV[1] == "help") { 
        print "  " ID,DATE
        print " --- " EX
        print " usage : " USAGE
        print "Options:"
        for (i in q) printf("+ %8s : %s\n",i,q[i])
        exit
    }

    for (i=0; i<=2; i++) {
        vlc[i]=i; vlj[i]=i
    }
    vlc["b"]=0; vlc["r"]=1; vlc["p"]=2
    vlj["m"]=0; vlj["r"]=1; vlj["b"]=2
    err=0
}

/setlinecap$/ {
    if (vlc[lc] != "") print vlc[lc] " setlinecap"
    next
}

/setlinejoin$/ {
    if (vlj[lj] != "") print vlj[lj] " setlinecap"
    next 
}

/setmiterlimit$/ {
    if (ml >= 0) print ml " setmiterlimit"
    next 
}

{
    print
}
