!= 蝨溷｣檎�莨晏ｰ惹ｿよ焚縺ｮ險ｭ螳�
!
!= set soil thermal diffusion coefficient
!
! Authors::   Yoshiyuki O. Takahashi
! Version::   $Id: soil_thermdiffcoef.f90,v 1.1 2015/01/29 12:12:21 yot Exp $
! Tag Name::  $Name:  $
! Copyright:: Copyright (C) GFD Dennou Club, 2008-2009. All rights reserved.
! License::   See COPYRIGHT[link:../../../COPYRIGHT]
!

module soil_thermdiffcoef

  !== References
  !
!!$  !  Matthews, E.,
!!$  !    Global vegetation and land use: New high-resolution data bases for climate
!!$  !    studies,
!!$  !    J. Clim. Appl. Meteor., 22, 474, 1983.
!!$  !
!!$  !  Matthews, E.,
!!$  !    Prescription of land-surface boundary conditions in GISS GCM II:
!!$  !    A simple method based on fine-resolution data bases,
!!$  !    NASA Technical memorandum #86096, 1984.

  ! 繝｢繧ｸ繝･繝ｼ繝ｫ蠑慕畑 ; USE statements
  !

  ! 遞ｮ蛻･蝙九ヱ繝ｩ繝｡繧ｿ
  ! Kind type parameter
  !
  use dc_types, only: DP, &      ! 蛟咲ｲｾ蠎ｦ螳滓焚蝙�. Double precision.
    &                 STRING     ! 譁�ｭ怜�.       Strings.

  ! 繝｡繝�そ繝ｼ繧ｸ蜃ｺ蜉�
  ! Message output
  !
  use dc_message, only: MessageNotify

  ! 螳｣險譁� ; Declaration statements
  !
  implicit none
  private

  ! 蜈ｬ髢区焔邯壹″
  ! Public procedure
  !
  public:: SetSoilThermDiffCoefSimple
  public:: SoilThermDiffCoefInit

  ! 蜈ｬ髢句､画焚
  ! Public variables
  !

  ! 髱槫�髢句､画焚
  ! Private variables
  !
  logical, save :: soil_thermdiffcoef_inited = .false.
                              ! 蛻晄悄險ｭ螳壹ヵ繝ｩ繧ｰ.
                              ! Initialization flag

  real(DP), save:: SoilThermDiffCoefMin
  real(DP), save:: SoilThermDiffCoefMax

  real(DP), save:: SoilMoistCritAmnt

  character(*), parameter:: module_name = 'soil_thermdiffcoef'
                              ! 繝｢繧ｸ繝･繝ｼ繝ｫ縺ｮ蜷咲ｧｰ.
                              ! Module name
  character(*), parameter:: version = &
    & '$Name:  $' // &
    & '$Id: soil_thermdiffcoef.f90,v 1.1 2015/01/29 12:12:21 yot Exp $'
                              ! 繝｢繧ｸ繝･繝ｼ繝ｫ縺ｮ繝舌�繧ｸ繝ｧ繝ｳ
                              ! Module version

contains

  !--------------------------------------------------------------------------------------

  subroutine SetSoilThermDiffCoefSimple( &
    & xy_SurfType, xy_SoilMoist,         & ! (in )
    & xy_SoilThermDiffCoef               & ! (out)
    & )

    ! 繝｢繧ｸ繝･繝ｼ繝ｫ蠑慕畑 ; USE statements
    !

    ! 譬ｼ蟄千せ險ｭ螳�
    ! Grid points settings
    !
    use gridset, only: imax, & ! 邨悟ｺｦ譬ｼ蟄千せ謨ｰ.
                               ! Number of grid points in longitude
      &                jmax, & ! 邱ｯ蠎ｦ譬ｼ蟄千せ謨ｰ.
                               ! Number of grid points in latitude
      &                kmax    ! 驩帷峩螻､謨ｰ.
                               ! Number of vertical level

    ! 螳｣險譁� ; Declaration statements
    !
    integer , intent(in ) :: xy_SurfType         ( 0:imax-1, 1:jmax )
    real(DP), intent(in ) :: xy_SoilMoist        ( 0:imax-1, 1:jmax )
    real(DP), intent(out) :: xy_SoilThermDiffCoef( 0:imax-1, 1:jmax )

    ! 菴懈･ｭ螟画焚
    ! Work variables
    !
    integer:: i               ! 邨悟ｺｦ譁ｹ蜷代↓蝗槭ｋ DO 繝ｫ繝ｼ繝礼畑菴懈･ｭ螟画焚
                              ! Work variables for DO loop in longitude
    integer:: j               ! 邱ｯ蠎ｦ譁ｹ蜷代↓蝗槭ｋ DO 繝ｫ繝ｼ繝礼畑菴懈･ｭ螟画焚
                              ! Work variables for DO loop in latitude

    ! 蛻晄悄蛹也｢ｺ隱�
    ! Initialization check
    !
    if ( .not. soil_thermdiffcoef_inited ) then
      call MessageNotify( 'E', module_name, 'This module has not been initialized.' )
    end if

    !
    ! land
    !
    do j = 1, jmax
      do i = 0, imax-1
        if( xy_SurfType( i, j ) >= 1 ) then
          xy_SoilThermDiffCoef(i,j) =                           &
            &   ( SoilThermDiffCoefMax - SoilThermDiffCoefMin ) &
            & / ( SoilMoistCritAmnt    - 0.0_DP               ) &
            & * ( xy_SoilMoist(i,j)    - 0.0_DP               ) &
            & + SoilThermDiffCoefMin
          xy_SoilThermDiffCoef(i,j) =                           &
            & min( max( xy_SoilThermDiffCoef(i,j), SoilThermDiffCoefMin ), &
            &      SoilThermDiffCoefMax )
        else
          xy_SoilThermDiffCoef(i,j) = 1.0e100_DP
        end if
      end do
    end do

  end subroutine SetSoilThermDiffCoefSimple

  !--------------------------------------------------------------------------------------

  subroutine SoilThermDiffCoefInit( &
    & FlagSnow &
    & )

    ! 繝｢繧ｸ繝･繝ｼ繝ｫ蠑慕畑 ; USE statements
    !

    ! 遞ｮ蛻･蝙九ヱ繝ｩ繝｡繧ｿ
    ! Kind type parameter
    !
    use dc_types, only: STDOUT ! 讓呎ｺ門�蜉帙�陬�ｽｮ逡ｪ蜿ｷ. Unit number of standard output

    ! 繝輔ぃ繧､繝ｫ蜈･蜃ｺ蜉幄｣懷勧
    ! File I/O support
    !
    use dc_iounit, only: FileOpen

    ! NAMELIST 繝輔ぃ繧､繝ｫ蜈･蜉帙↓髢｢縺吶ｋ繝ｦ繝ｼ繝�ぅ繝ｪ繝�ぅ
    ! Utilities for NAMELIST file input
    !
    use namelist_util, only: namelist_filename, NmlutilMsg

    ! 繝舌こ繝�Δ繝�Ν
    ! Bucket model
    !
    use Bucket_Model, only : &
      & BucketGetSoilMoistCritAmnt, &
      & BucketModelInit

    logical, intent(in) :: FlagSnow

    ! 菴懈･ｭ螟画焚
    ! Work variables
    !
    integer:: unit_nml        ! NAMELIST 繝輔ぃ繧､繝ｫ繧ｪ繝ｼ繝励Φ逕ｨ陬�ｽｮ逡ｪ蜿ｷ.
                              ! Unit number for NAMELIST file open
    integer:: iostat_nml      ! NAMELIST 隱ｭ縺ｿ霎ｼ縺ｿ譎ゅ� IOSTAT.
                              ! IOSTAT of NAMELIST read

    ! NAMELIST 螟画焚鄒､
    ! NAMELIST group name
    !
    namelist /soil_thermdiffcoef_nml/ &
      & SoilThermDiffCoefMin, &
      & SoilThermDiffCoefMax

    ! 螳溯｡梧枚 ; Executable statement
    !

    if ( soil_thermdiffcoef_inited ) return

    ! 繝�ヵ繧ｩ繝ｫ繝亥､縺ｮ險ｭ螳�
    ! Default values settings
    !

    SoilThermDiffCoefMin = 0.2_DP
    SoilThermDiffCoefMax = 2.0_DP
                     !   thermal conductivity (W m-1 K-1)

    ! NAMELIST 縺ｮ隱ｭ縺ｿ霎ｼ縺ｿ
    ! NAMELIST is input
    !
    if ( trim(namelist_filename) /= '' ) then
      call FileOpen( unit_nml, &          ! (out)
        & namelist_filename, mode = 'r' ) ! (in)

      rewind( unit_nml )
      read( unit_nml,                   &  ! (in)
        & nml = soil_thermdiffcoef_nml, &  ! (out)
        & iostat = iostat_nml           &  ! (out)
        & )
      close( unit_nml )

      call NmlutilMsg( iostat_nml, module_name ) ! (in)
      if ( iostat_nml == 0 ) write( STDOUT, nml = soil_thermdiffcoef_nml )
    end if

    ! 繝舌こ繝�Δ繝�Ν
    ! Bucket model
    !
    call BucketModelInit( &
      & FlagSnow          & ! (in)
      & )
    SoilMoistCritAmnt = BucketGetSoilMoistCritAmnt()

    ! 蜊ｰ蟄� ; Print
    !
    call MessageNotify( 'M', module_name, '----- Initialization Messages -----' )
    call MessageNotify( 'M', module_name, 'SoilThermDiffCoefMin = %f', d = (/SoilThermDiffCoefMin/) )
    call MessageNotify( 'M', module_name, 'SoilThermDiffCoefMax = %f', d = (/SoilThermDiffCoefMax/) )
    call MessageNotify( 'M', module_name, 'SoilMoistCritAmnt    = %f', d = (/SoilMoistCritAmnt/) )
    call MessageNotify( 'M', module_name, '-- version = %c', c1 = trim(version) )

    soil_thermdiffcoef_inited = .true.

  end subroutine SoilThermDiffCoefInit

  !--------------------------------------------------------------------------------------

end module soil_thermdiffcoef