! Sample program for gtool_history/gtool4 and ISPACK   2001/11/12 S.Takehiro
! 
! Solving KdV equation
!     d\zeta/dt  = -\zeta d\zeta/dx + d^3\zeta/dx^3
!
program kdv

  use n2pack
  use gtool_history
  implicit none

 !---- 空間解像度設定 ----
  integer, parameter :: im=32, jm=32            ! 格子点の設定(X,Y)
  integer, parameter :: km=10, lm=10            ! 切断波数の設定(X,Y)

 !---- 変数 ----
  real(8)            :: gzeta(0:jm-1,0:im-1)    ! 格子データ
  real(8)            :: szeta(-lm:lm,-km:km)    ! スペクトルデータ
  real(8)            :: szeta0(-lm:lm,-km:km)    ! スペクトルデータ
  real(8)            :: szeta1(-lm:lm,-km:km)    ! スペクトルデータ

 !---- 座標変数など ----
  real(8)            :: gx(0:jm-1,0:im-1), gy(0:jm-1,0:im-1)
  real(8), parameter :: xmin=0.0, xmax=1.0
  real(8), parameter :: ymin=0.0, ymax=1.0

 !---- 時間積分パラメター ----
  real(8), parameter :: dt=1e-6                 ! 時間ステップ間隔
  integer, parameter :: nt=1000, ndisp=50       ! 時間積分数, 表示ステップ

 !---- 物理パラメター ----
  real(8), parameter :: x1=(xmin+xmax)/2.0      ! 初期分布 X 座標
  real(8), parameter :: u1=720.0                  ! 初期分布の振幅

  real(8) :: pi                                 ! 円周率
  integer :: i, j, it                           ! DO 変数

  pi = 4.0D0*atan(1.0D0)

 !---------------- 座標値の設定 ---------------------
  do i=0,im-1
     do j=0,jm-1
        gx(j,i)= (xmax-xmin)/im*i
        gy(j,i)= (ymax-ymin)/jm*j
     enddo
  enddo

  call n2initial(im,jm,km,lm,xmax-xmin,ymax-ymin)    ! スペクトル初期化

 !------------------- 初期値設定 ----------------------
  !gzeta=  cos(pi*gx)
  gzeta= u1*sech((gx-x1)/sqrt(12/u1))**2 

  szeta = s_g(gzeta)
  szeta1 = szeta ; szeta0 = szeta

  call output_gtool4_init                            ! ヒストリー初期化
  call output_gtool4

 !------------------- 時間積分 ----------------------
  do it=1,nt
     szeta = szeta0 + 2*dt * &                       ! Euler 法による時間積分
          ( -s_g(g_s(szeta1)*g_s(s_dx_s(szeta1))) &
            - s_dx_s(s_dx_s(s_dx_s(szeta1)))  )
     szeta0=szeta1 ; szeta1=szeta

     if(mod(it,ndisp) .eq. 0)then                    ! 出力
        gzeta = g_s(szeta)
        call output_gtool4
     endif
  enddo

  call output_gtool4_close                           ! ヒストリー後処理
  stop

contains
  function sech(x)
    double precision :: x(0:jm-1,0:im-1)
    double precision :: sech(0:jm-1,0:im-1)

    sech = 2/(exp(x)+ exp(-x))

  end function sech

  subroutine output_gtool4_init
    call HistoryCreate( &                                  ! ヒストリー作成
           file='kdv.nc', title='KDV equation model',   &
           source='Sample program of gtool_history/gtool4', &
           institution='GFD_Dennou Club davis project',     &
           dims=(/'x','y','t'/), dimsizes=(/im,jm,0/),      &
           longnames=(/'X-coordinate','Y-coordinate','time        '/),&
           units=(/'1','1','1'/),                           &
           origin=0.0, interval=real(ndisp*dt) )

    call HistoryPut('x',gx(0,0:im-1))                         ! 変数出力
    call HistoryPut('y',gy(0:jm-1,0))                         ! 変数出力

    call HistoryAddVariable( &                                ! 変数定義
           varname='zeta', dims=(/'x','y','t'/), & 
           longname='vorticity', units='1', xtype='double')
  end subroutine output_gtool4_init

  subroutine output_gtool4
    write(6,*) 'it = ',it
    call HistoryPut('zeta',transpose(gzeta))
  end subroutine output_gtool4

  subroutine output_gtool4_close
    call HistoryClose
  end subroutine output_gtool4_close

end program kdv
