! Sample program for gtool_history/gtool4 and ISPACK   2001/11/12 S.Takehiro
! 
! Solving 2-D shallow water fluid system
!     du/dt  - fv  =  -g dh/dx,
!     dv/dt  + fu  =  -g dh/dy,
!     dh/dt + H( du/dx + dv/dy ) = 0.
!
program shall_n

  use n2pack
  use gtool_history
  implicit none

 !---- 空間解像度設定 ----
  integer, parameter :: im=32, jm=32            ! 格子点の設定(X,Y)
  integer, parameter :: km=10, lm=10            ! 切断波数の設定(X,Y)

 !---- 変数 ----
  real(8)            :: gu(0:jm-1,0:im-1)       ! 格子データ(X 速度)
  real(8)            :: gv(0:jm-1,0:im-1)       ! 格子データ(Y 速度)
  real(8)            :: gh(0:jm-1,0:im-1)       ! 格子データ(高度)

  real(8)            :: su(-lm:lm,-km:km)       ! スペクトルデータ
  real(8)            :: sv(-lm:lm,-km:km)       ! スペクトルデータ
  real(8)            :: sh(-lm:lm,-km:km)       ! スペクトルデータ

  real(8)            :: gzeta(0:jm-1,0:im-1)    ! 格子データ(渦度)
  real(8)            :: szeta(-lm:lm,-km:km)    ! スペクトルデータ

 !---- 座標変数など ----
  real(8)            :: gx(0:jm-1,0:im-1), gy(0:jm-1,0:im-1)
  real(8), parameter :: xmin=0.0, xmax=1.0
  real(8), parameter :: ymin=0.0, ymax=1.0

 !---- 粘性設定 ----
  real(8), parameter :: nu=1e-17             ! 粘性係数
  integer, parameter :: nv=5                 ! 粘性の階数
  real(8)            :: snu(-lm:lm,-km:km)   ! スペクトルデータ

 !---- 時間積分パラメター ----
  real(8), parameter :: dt=1d-2                 ! 時間ステップ間隔
  integer, parameter :: nt=1000, ndisp=50       ! 時間積分数, 表示ステップ

 !---- 物理パラメター ----
  real(8), parameter :: grav=1.0                ! 重力
  real(8), parameter :: H0=0.05                 ! 平均深さ
  real(8), parameter :: f=0.0                   ! コリオリパラメター

  real(8), parameter  :: x1=(xmax-xmin)*0.4     ! 初期渦1位置 X 座標
  real(8), parameter  :: y1=(ymax-ymin)*0.4     ! 初期渦1位置 Y 座標
  real(8), parameter  :: x2=(xmax-xmin)*0.6     ! 初期渦2位置 X 座標
  real(8), parameter  :: y2=(ymax-ymin)*0.6     ! 初期渦2位置 Y 座標
  real(8), parameter  :: sigma=0.05             ! 初期渦の大きさ

  real(8), parameter :: pi=3.141592653589793
  integer :: i, j, k, l, it                     ! DO 変数

 !---------------- 座標値の設定 ---------------------
  do i=0,im-1
     do j=0,jm-1
        gx(j,i)= (xmax-xmin)/im*i
        gy(j,i)= (ymax-ymin)/jm*j
     enddo
  enddo

  call n2initial(im,jm,km,lm,xmax-xmin,ymax-ymin)    ! スペクトル初期化

 !------------------- 粘性設定 ----------------------
  do k=-km,km
     do l=-lm,lm
        snu(l,k)=nu*((2*pi*k/(xmax-xmin))**2+(2*pi*l/(ymax-ymin))**2)**nv
     enddo
  enddo

 !------------------- 初期値設定 ----------------------
  gzeta=  exp(-((gx-x1)**2+(gy-y1)**2)/(2*sigma**2)) &
       + exp(-((gx-x2)**2+(gy-y2)**2)/(2*sigma**2))
  szeta =  s_g(gzeta) ; szeta(0,0)=0.0 ; gzeta= g_s(szeta)

  gh = 0.0 ; sh = s_g(gh)
  su = -s_dy_s(s_laplainv_s(s_g(gzeta)))
  sv =  s_dx_s(s_laplainv_s(s_g(gzeta)))
  gu = g_s(su) ; gv = g_s(sv)
  gzeta = g_s(s_dx_s(sv)-s_dy_s(su))

  call output_gtool4_init                            ! ヒストリー初期化
  call output_gtool4

 !------------------- 時間積分 ----------------------
  do it=1,nt
     su = ( su + dt * ( &                              ! 時間積分
                   - s_dx_s(s_g(gu*gu)) - s_dy_s(s_g(gu*gv)) &
                   + f * sv - grav * s_dx_s(sh) ) ) &
          /(1+snu*dt)

     sv = ( sv + dt * ( &
                   - s_dx_s(s_g(gu*gv)) - s_dy_s(s_g(gv*gv)) &
                   - f * su - grav * s_dy_s(sh) ) ) &
          /(1+snu*dt)

     sh = sh + dt * ( & 
          H0 *( -s_dx_s(su) - s_dy_s(sv) ) &
          - s_dx_s(s_g(gh*gu)) - s_dy_s(s_g(gh*gv)) )

     gu = g_s(su) ; gv = g_s(sv) ; gh = g_s(sh)
     gzeta = g_s(s_dx_s(sv)-s_dy_s(su))

     if(mod(it,ndisp) .eq. 0)then                    ! 出力
        call output_gtool4
     endif
  enddo

  call output_gtool4_close                           ! ヒストリー後処理
  stop

contains

  subroutine output_gtool4_init
    call HistoryCreate( &                                  ! ヒストリー作成
           file='shall_n.nc', title='2D nonlinear shallow water model', &
           source='Sample program of gtool_history/gtool4', &
           institution='GFD_Dennou Club davis project',     &
           dims=(/'x','y','t'/), dimsizes=(/im,jm,0/),      &
           longnames=(/'X-coordinate','Y-coordinate','time        '/),&
           units=(/'m','m','s'/),                           &
           origin=0.0, interval=real(ndisp*dt) )

    call HistoryPut('x',gx(0,0:im-1))                         ! 変数出力
    call HistoryPut('y',gy(0:jm-1,0))                         ! 変数出力

    call HistoryAddVariable( &                                ! 変数定義
           varname='u', dims=(/'x','y','t'/), & 
           longname='U-velocity', units='m/s', xtype='double')
    call HistoryAddVariable( &                                ! 変数定義
           varname='v', dims=(/'x','y','t'/), & 
           longname='V-velocity', units='m/s', xtype='double')
    call HistoryAddVariable( &                                ! 変数定義
           varname='h', dims=(/'x','y','t'/), & 
           longname='height', units='m', xtype='double')
    call HistoryAddVariable( &                                ! 変数定義
           varname='zeta', dims=(/'x','y','t'/), & 
           longname='vorticity', units='1/s', xtype='double')
  end subroutine output_gtool4_init

  subroutine output_gtool4
    write(6,*) 'it = ',it
    call HistoryPut('u',transpose(gu))
    call HistoryPut('v',transpose(gv))
    call HistoryPut('h',transpose(gh))
    call HistoryPut('zeta',transpose(gzeta))
  end subroutine output_gtool4

  subroutine output_gtool4_close
    call HistoryClose
  end subroutine output_gtool4_close

end program shall_n
