!----------------------------------------------------------------------
!     Copyright (c) 2001 Shin-ichi Takehiro. All rights reserved.
!----------------------------------------------------------------------
! Sample program for gtool_history/gtool4 and ISPACK   2001/12/26 S.Takehiro
! 
! Solving 2-D non-divergent (barotropic) fluid system
!     d\zeta/dt  = \nu\nabla^2\zeta
!
program c2_diffusion

  use c2pack
  use gtool_history
  implicit none

 !---- 空間解像度設定 ----
  integer, parameter :: im=32, jm=32            ! 格子点の設定(X,Y)
  integer, parameter :: km=10, lm=10            ! 切断波数の設定(X,Y)

 !---- 変数 ----
  real(8)            :: gg_zeta(0:jm,0:im-1)    ! 格子データ
  real(8)            :: es_zeta(-km:km,lm)      ! スペクトルデータ

 !---- 座標変数など ----
  real(8)            :: gg_x(0:jm,0:im-1), gg_y(0:jm,0:im-1)
  real(8), parameter :: xmin=0.0, xmax=1.0
  real(8), parameter :: ymin=0.0, ymax=1.0

 !---- 時間積分パラメター ----
  real(8), parameter :: dt=1e-4                 ! 時間ステップ間隔
  integer, parameter :: nt=1000, ndisp=100      ! 時間積分数, 表示ステップ

 !---- 物理パラメター ----
  real(8), parameter :: nu=1.0                  ! 粘性係数
  real(8), parameter :: x1=(xmin+xmax)/2.0      ! 初期分布 X 座標
  real(8), parameter :: y1=(xmin+xmax)/2.0      ! 初期分布 Y 座標
  real(8), parameter :: sigma=0.1               ! 初期分布の大きさ

  integer :: i, j, it                           ! DO 変数


 !---------------- 座標値の設定 ---------------------
  do i=0,im-1
     do j=0,jm
        gg_x(j,i)= (xmax-xmin)/im*i
        gg_y(j,i)= (ymax-ymin)/jm*j
     enddo
  enddo

  call c2initial(im,jm,km,lm,xmax-xmin,ymax-ymin)    ! スペクトル初期化

 !------------------- 初期値設定 ----------------------
  gg_zeta=  exp(-((gg_x-x1)**2+(gg_y-y1)**2)/(2*sigma**2))
  es_zeta = es_gg(gg_zeta)

  call output_gtool4_init                            ! ヒストリー初期化
  call output_gtool4

 !------------------- 時間積分 ----------------------
  do it=1,nt                                         ! Euler 法による時間積分
     es_zeta = es_zeta + dt * nu * es_lapla_es(es_zeta) 

     if(mod(it,ndisp) .eq. 0)then                    ! 出力
        gg_zeta = gg_es(es_zeta)
        call output_gtool4
     endif
  enddo

  call output_gtool4_close                           ! ヒストリー後処理
  stop

contains

  subroutine output_gtool4_init
    call HistoryCreate( &                                  ! ヒストリー作成
           file='diff_s.nc', title='2D diffusion model', &
           source='Sample program of gtool_history/gtool4', &
           institution='GFD_Dennou Club davis project',     &
           dims=(/'x','y','t'/), dimsizes=(/im,jm+1,0/),      &
           longnames=(/'X-coordinate','Y-coordinate','time        '/),&
           units=(/'1','1','1'/),                           &
           origin=0.0, interval=real(ndisp*dt) )

    call HistoryPut('x',gg_x(0,0:im-1))                        ! 変数出力
    call HistoryPut('y',gg_y(0:jm,0))                          ! 変数出力

    call HistoryAddVariable( &                                ! 変数定義
           varname='zeta', dims=(/'x','y','t'/), & 
           longname='vorticity', units='1', xtype='double')
  end subroutine output_gtool4_init

  subroutine output_gtool4
    write(6,*) 'it = ',it
    call HistoryPut('zeta',transpose(gg_zeta))
  end subroutine output_gtool4

  subroutine output_gtool4_close
    call HistoryClose
  end subroutine output_gtool4_close

end program c2_diffusion
