! Sample program for gtool_history/gtool4 and ISPACK   2001/12/26 S.Takehiro
! 
! Solving 2-D non-divergent (barotropic) fluid system
!     d\zeta/dt  = - c_x d\zeta/dx - c_y d\zeta/dy
!
program n2_advection

  use n2pack
  use gtool_history
  implicit none

 !---- 空間解像度設定 ----
  integer, parameter :: im=32, jm=32            ! 格子点の設定(X,Y)
  integer, parameter :: km=10, lm=10            ! 切断波数の設定(X,Y)

 !---- 変数 ----
  real(8)            :: gg_zeta(0:jm-1,0:im-1)  ! 格子データ
  real(8)            :: ee_zeta0(-lm:lm,-km:km) ! スペクトルデータ(t-dt)
  real(8)            :: ee_zeta1(-lm:lm,-km:km) ! スペクトルデータ(t)
  real(8)            :: ee_zeta2(-lm:lm,-km:km) ! スペクトルデータ(t+dt)

 !---- 座標変数など ----
  real(8)            :: gg_x(0:jm-1,0:im-1), gg_y(0:jm-1,0:im-1)
  real(8), parameter :: xmin=0.0, xmax=1.0
  real(8), parameter :: ymin=0.0, ymax=1.0

 !---- 時間積分パラメター ----
  real(8), parameter :: dt=1e-2                 ! 時間ステップ間隔
  integer, parameter :: nt=1000, ndisp=5        ! 時間積分数, 表示ステップ

 !---- 物理パラメター ----
  real(8), parameter :: cx=1.0, cy=0.5          ! 位相速度

  real(8), parameter :: x1=(xmin+xmax)/2.0      ! 初期分布 X 座標
  real(8), parameter :: y1=(xmin+xmax)/2.0      ! 初期分布 Y 座標
  real(8), parameter :: sigma=0.1               ! 初期分布の大きさ

  integer :: i, j, it                           ! DO 変数

 !---------------- 座標値の設定 ---------------------
  do i=0,im-1
     do j=0,jm-1
        gg_x(j,i)= (xmax-xmin)/im*i
        gg_y(j,i)= (ymax-ymin)/jm*j
     enddo
  enddo

  call n2initial(im,jm,km,lm,xmax-xmin,ymax-ymin)    ! スペクトル初期化

 !------------------- 初期値設定 ----------------------
  gg_zeta=  exp(-((gg_x-x1)**2+(gg_y-y1)**2)/(2*sigma**2))
  !gg_zeta=  sin(2*pi*gg_x)
  ee_zeta1 = ee_gg(gg_zeta)
  ee_zeta0 = ee_zeta1

  call output_gtool4_init                            ! ヒストリー初期化
  call output_gtool4

 !------------------- 時間積分 ----------------------
  do it=1,nt
     ee_zeta2 = ee_zeta0 &                           ! Leap frog による時間積分
            + 2 * dt * ( - cx * ee_dx_ee(ee_zeta1) &
                         - cy * ee_dy_ee(ee_zeta1) ) 
     ee_zeta0 = ee_zeta1 ; ee_zeta1 = ee_zeta2

     if(mod(it,ndisp) .eq. 0)then                    ! 出力
        gg_zeta = gg_ee(ee_zeta1)
        call output_gtool4
     endif
  enddo

  call output_gtool4_close                           ! ヒストリー後処理
  stop

contains

  subroutine output_gtool4_init
    call HistoryCreate( &                                  ! ヒストリー作成
           file='advect.nc', title='2D advection model',    &
           source='Sample program of gtool_history/gtool4', &
           institution='GFD_Dennou Club davis project',     &
           dims=(/'x','y','t'/), dimsizes=(/im,jm,0/),      &
           longnames=(/'X-coordinate','Y-coordinate','time        '/),&
           units=(/'1','1','1'/),                           &
           origin=0.0, interval=real(ndisp*dt) )

    call HistoryPut('x',gg_x(0,0:im-1))                         ! 変数出力
    call HistoryPut('y',gg_y(0:jm-1,0))                         ! 変数出力

    call HistoryAddVariable( &                                ! 変数定義
           varname='zeta', dims=(/'x','y','t'/), & 
           longname='vorticity', units='1', xtype='double')
  end subroutine output_gtool4_init

  subroutine output_gtool4
    write(6,*) 'it = ',it
    call HistoryPut('zeta',transpose(gg_zeta))
  end subroutine output_gtool4

  subroutine output_gtool4_close
    call HistoryClose
  end subroutine output_gtool4_close

end program n2_advection
