! Sample program for gtool_history/gtool4 and ISPACK   2001/12/26 S.Takehiro
! 
! Solving 2-D shallow water fluid system
!     du/dt  - fv  =  -g dh/dx,
!     dv/dt  + fu  =  -g dh/dy,
!     dh/dt + H( du/dx + dv/dy ) = 0.
!
program shall_l

  use n2pack
  use gtool_history
  implicit none

 !---- 空間解像度設定 ----
  integer, parameter :: im=32, jm=32            ! 格子点の設定(X,Y)
  integer, parameter :: km=10, lm=10            ! 切断波数の設定(X,Y)

 !---- 変数 ----
  real(8)            :: gg_u(0:jm-1,0:im-1)     ! 格子データ(X 速度)
  real(8)            :: gg_v(0:jm-1,0:im-1)     ! 格子データ(Y 速度)
  real(8)            :: gg_h(0:jm-1,0:im-1)     ! 格子データ(高度)

  real(8)            :: ee_u(-lm:lm,-km:km)     ! スペクトルデータ
  real(8)            :: ee_v(-lm:lm,-km:km)     ! スペクトルデータ
  real(8)            :: ee_h(-lm:lm,-km:km)     ! スペクトルデータ

 !---- 座標変数など ----
  real(8)            :: gg_x(0:jm-1,0:im-1), gg_y(0:jm-1,0:im-1)
  real(8), parameter :: xmin=0.0, xmax=1d7
  real(8), parameter :: ymin=0.0, ymax=1d7

 !---- 時間積分パラメター ----
  real(8), parameter :: dt=1d3                  ! 時間ステップ間隔
  integer, parameter :: nt=1000, ndisp=50       ! 時間積分数, 表示ステップ

 !---- 物理パラメター ----
  real(8), parameter :: grav=9.8                ! 重力
  real(8), parameter :: H0=4000.0               ! 平均深さ
  real(8), parameter :: f=1e-4                  ! コリオリパラメター

  real(8), parameter :: x1=(xmin+xmax)/2.0      ! 初期分布 X 座標
  real(8), parameter :: y1=(xmin+xmax)/2.0      ! 初期分布 Y 座標
  real(8), parameter :: sigma=1.0d6             ! 初期分布の大きさ

  integer :: i, j, it                           ! DO 変数

 !---------------- 座標値の設定 ---------------------
  do i=0,im-1
     do j=0,jm-1
        gg_x(j,i)= (xmax-xmin)/im*i
        gg_y(j,i)= (ymax-ymin)/jm*j
     enddo
  enddo

  call n2initial(im,jm,km,lm,xmax-xmin,ymax-ymin)    ! スペクトル初期化

 !------------------- 初期値設定 ----------------------
  gg_h = exp(-((gg_x-x1)**2+(gg_y-y1)**2)/(2*sigma**2))
  gg_u = 0.0
  gg_v = 0.0

  ee_u = ee_gg(gg_u) ; ee_v = ee_gg(gg_v) ; ee_h = ee_gg(gg_h)

  call output_gtool4_init                            ! ヒストリー初期化
  call output_gtool4

 !------------------- 時間積分 ----------------------
  do it=1,nt
     ee_u = ee_u + dt * (   f * ee_v - grav * ee_dx_ee(ee_h) )      ! 時間積分
     ee_v = ee_v + dt * ( - f * ee_u - grav * ee_dy_ee(ee_h) )
     ee_h = ee_h + dt * H0 * ( -ee_dx_ee(ee_u) - ee_dy_ee(ee_v) ) 

     if(mod(it,ndisp) .eq. 0)then                    ! 出力
        gg_u = gg_ee(ee_u) ; gg_v = gg_ee(ee_v) ; gg_h = gg_ee(ee_h)
        call output_gtool4
     endif
  enddo

  call output_gtool4_close                           ! ヒストリー後処理
  stop

contains

  subroutine output_gtool4_init
    call HistoryCreate( &                                  ! ヒストリー作成
           file='shall_l.nc', title='2D shallow water model', &
           source='Sample program of gtool_history/gtool4', &
           institution='GFD_Dennou Club davis project',     &
           dims=(/'x','y','t'/), dimsizes=(/im,jm,0/),      &
           longnames=(/'X-coordinate','Y-coordinate','time        '/),&
           units=(/'m','m','s'/),                           &
           origin=0.0, interval=real(ndisp*dt) )

    call HistoryPut('x',gg_x(0,0:im-1))                         ! 変数出力
    call HistoryPut('y',gg_y(0:jm-1,0))                         ! 変数出力

    call HistoryAddVariable( &                                ! 変数定義
           varname='u', dims=(/'x','y','t'/), & 
           longname='U-velocity', units='m/s', xtype='double')
    call HistoryAddVariable( &                                ! 変数定義
           varname='v', dims=(/'x','y','t'/), & 
           longname='V-velocity', units='m/s', xtype='double')
    call HistoryAddVariable( &                                ! 変数定義
           varname='h', dims=(/'x','y','t'/), & 
           longname='height', units='m', xtype='double')
  end subroutine output_gtool4_init

  subroutine output_gtool4
    write(6,*) 'it = ',it
    call HistoryPut('u',transpose(gg_u))
    call HistoryPut('v',transpose(gg_v))
    call HistoryPut('h',transpose(gg_h))
  end subroutine output_gtool4

  subroutine output_gtool4_close
    call HistoryClose
  end subroutine output_gtool4_close

end program shall_l
