!----------------------------------------------------------------------
!     Copyright (c) 2002 Shin-ichi Takehiro. All rights reserved.
!----------------------------------------------------------------------
!
!表題  SPCPACK/ISPACK-F90 
!      球殻内の温度拡散問題
!
!履歴  2002/02/04  竹広真一
!
program spcdiff1

  use spcpack
  use gtool_history
  implicit none

 !---- 空間解像度設定 ----
  integer,parameter  :: im=32, jm=16, km=16  ! 格子点の設定(経度, 緯度, 動径)
  integer,parameter  :: nm=10, lm=16         ! 切断波数の設定(水平, 動径)

 !---- 座標変数など ----
  real(8),parameter  :: ri=0.5, ro=1.5       ! 内外半径

 !---- 変数 ----
  real(8), dimension(im,jm,0:km)     :: ggg_temp   ! 温度
  real(8), dimension((nm+1)**2,0:lm) :: yt_temp    ! 温度

  real(8), dimension(im,jm,0:km)     :: ggg_q      ! 熱源
  real(8), dimension((nm+1)**2,0:lm) :: yt_q       ! 熱源

  real(8)             :: gg_tempbndry(im,jm,2)     ! 境界値
  real(8)             :: y_tempbndry((nm+1)**2,2)  ! 境界値

 !---- 時間積分パラメター ----
  real(8), parameter :: dt=1e-5                 ! 時間ステップ間隔
  integer, parameter :: nt=10000, ndisp=1000    ! 時間積分数, 表示ステップ

 !---- 物理パラメター ----
  character(len=2), parameter :: tempbc='DN'    ! 温度境界条件(DD/DN/ND/NN)
  real(8), parameter :: nu=1.0                  ! 粘性係数

  real(8), parameter :: pi=3.1415926535897932385D0
  real(8), parameter :: lon1=pi                 ! 初期分布緯度座標
  real(8), parameter :: lat1=0.0                ! 初期分布経度座標
  real(8), parameter :: rad1=(ri+ro)/2.0        ! 初期分布動径座標
  real(8), parameter :: sigma=0.2               ! 初期分布の大きさ

 !---- その他 ----
  integer :: it


 !---------------- 座標値の設定 ---------------------
  call spcinitial(im,jm,km,nm,lm,ri,ro)

 !------------------- 初期値設定 ----------------------
  ggg_temp =  exp(-((ggg_lon-lon1)**2+(ggg_lat-lat1)**2+(ggg_rad-rad1)**2)&
                 /(2*sigma**2))
  yt_temp = yt_ggg(ggg_temp)

  ggg_q = 1.0
  yt_q = yt_ggg(ggg_q)

 !------------------- 境界値設定 ----------------------
  gg_tempbndry(:,:,1) = 0
  gg_tempbndry(:,:,2) = 0

  y_tempbndry(:,1) = y_gg(gg_tempbndry(:,:,1))
  y_tempbndry(:,2) = y_gg(gg_tempbndry(:,:,2))

  call output_gtool4_init
  call output_gtool4

 !------------------- 時間積分 ----------------------
  do it=1,nt                                         ! Euler 法による時間積分
     yt_temp = yt_temp + dt *( nu * yt_lapla_yt(yt_temp) + yt_q )
     call ytboundaries(yt_temp,y_tempbndry,cond=tempbc)

     if(mod(it,ndisp) .eq. 0)then                    ! 出力
        ggg_temp = ggg_yt(yt_temp)
        call output_gtool4
     endif
  enddo
  call output_gtool4_close

contains

  subroutine output_gtool4_init
    call HistoryCreate( &                                  ! ヒストリー作成
           file='spcdiff1.nc', title='Diffusion model in a spherical shell', &
           source='Sample program of gtool_history/gtool4', &
           institution='GFD_Dennou Club davis project',     &
           dims=(/'lon','lat','rad','t  '/), dimsizes=(/im,jm,km+1,0/),&
           longnames=(/'Latitude ','Longitude','Radius   ','time     '/),&
           units=(/'1','1','1','1'/),   &
           origin=0.0, interval=real(ndisp*dt) )

    call HistoryPut('lon',g_lon/pi*180)                       ! 変数出力
    call HistoryPut('lat',g_lat/pi*180)                       ! 変数出力
    call HistoryPut('rad',g_rad)                              ! 変数出力

    call HistoryAddVariable( &                                ! 変数定義
           varname='temp', dims=(/'lon','lat','rad','t  '/), & 
           longname='temperature', units='1', xtype='double')
  end subroutine output_gtool4_init

  subroutine output_gtool4
    write(6,*) 'it = ',it
    call HistoryPut('t',real(it*dt))
    call HistoryPut('temp',ggg_temp)
  end subroutine output_gtool4

  subroutine output_gtool4_close
    call HistoryClose
  end subroutine output_gtool4_close

end program spcdiff1
