!----------------------------------------------------------------------
!     Copyright (c) 2002 Shin-ichi Takehiro. All rights reserved.
!----------------------------------------------------------------------
!
!表題  T2PACK/ISPACK-F90 
!      ブシネスク対流モデル Free-slip only
!
!履歴  2002/01/25  竹広真一
!
program bsnconv

  use t2pack
  use gtool_history
  implicit none

 !---- 空間解像度設定 ----
  integer, parameter  :: im=128, jm=32      ! 格子点の設定(X,Y)
  integer, parameter  :: km=42, lm=21       ! 切断波数の設定(X,Y)

 !---- 座標変数など ----
  real(8), parameter  :: xmin=0, xmax=8     ! X 座標範囲
  real(8), parameter  :: ymin=0, ymax=1     ! Y 座標範囲

 !---- 変数 ----
  real(8)             :: gg_psi(0:jm,0:im-1)    ! 格子データ(流線)
  real(8)             :: gg_temp(0:jm,0:im-1)   ! 格子データ(温度/温度擾乱)
  real(8)             :: gg_zeta(0:jm,0:im-1)   ! 格子データ(渦度)

  real(8)             :: et_psi(-km:km,0:lm)    ! スペクトルデータ(流線)
  real(8)             :: et_temp(-km:km,0:lm)   ! スペクトルデータ(温度擾乱)
  real(8)             :: et_zeta(-km:km,0:lm)   ! スペクトルデータ(渦度)

  real(8)             :: g_tempbndry(0:im-1,2)  ! 境界値
  real(8)             :: e_tempbndry(-km:km,2)  ! 境界値

  real(8)             :: e_zetabndry(-km:km,2)  ! 境界値

 !---- 時間積分パラメター ----

  real(8), parameter :: dt=5e-6                 ! 時間ステップ間隔
  integer, parameter :: nt=100000, ndisp=5000   ! 時間積分数, 表示ステップ

 !---- 物理パラメター ----
  character(len=2), parameter :: tempbc='DD'    ! 温度境界条件(DD/DN/ND/NN)
  real(8), parameter :: Ra=1.0e4                ! レイリー数
  real(8), parameter :: Pr=1.0                  ! プランドル数

 !---- その他 ----
  real(8), parameter  :: pi=3.1415926535897932385D0
  integer :: it

 !---------------- 座標値の設定 ---------------------
  call t2initial(im,jm,km,lm,xmin,xmax,ymin,ymax)

 !------------------- 初期値設定 ----------------------
  gg_temp = 1 -gg_y
  gg_temp(jm/2,im/2) = gg_temp(jm/2,im/2) + 0.01        ! 温度擾乱場
  gg_psi  = 0.0
  gg_zeta = 0.0

  et_temp = et_gg(gg_temp)
  et_psi  = et_gg(gg_psi)
  et_zeta = et_gg(gg_zeta)

 !------------------- 境界値設定 ----------------------

  g_tempbndry(:,1) = 0
  g_tempbndry(:,2) = 1
  e_tempbndry(:,1) = e_g(g_tempbndry(:,1))
  e_tempbndry(:,2) = e_g(g_tempbndry(:,2))

  e_zetabndry = 0

  call output_gtool4_init                            ! ヒストリー初期化
  call output_gtool4

 !------------------- 時間積分 ----------------------
  do it=1,nt                                         ! Euler 法による時間積分
     et_temp = et_temp + &
          dt*( -et_jacobian_et_et(et_psi,et_temp) &
               + et_lapla_et(et_temp) )

     call etboundaries(et_temp,e_tempbndry,cond=tempbc)

     et_zeta = et_zeta + &
          dt*( - et_jacobian_et_et(et_psi,et_zeta) &
               + Pr*Ra*et_dx_et(et_temp) + Pr*et_lapla_et(et_zeta)    )

     call etboundaries(et_zeta,e_zetabndry,cond='DD')

     et_psi = et_laplainv_et(et_zeta)

     if(mod(it,ndisp) .eq. 0)then                    ! 出力
        gg_zeta = gg_et(et_zeta)
        call output_gtool4
     endif
  enddo

  call output_gtool4_close                           ! ヒストリー後処理
  stop

contains

    subroutine output_gtool4_init
      call HistoryCreate( &                               ! ヒストリー作成
           file='t2pack_bsnconv1.nc', title='Boussinesq convection (TT)', &
           source='Sample program of gtool_history/gtool4', &
           institution='GFD_Dennou Club davis/spmodel project',&
           dims=(/'x','y','t'/), dimsizes=(/im,jm+1,0/),    &
           longnames=(/'X-coordinate','Y-coordinate','time        '/),&
           units=(/'1','1','1'/),                           &
           origin=0.0, interval=real(ndisp*dt) )

      call HistoryPut('x',g_x)                            ! 変数出力
      call HistoryPut('y',g_y)                            ! 変数出力

      call HistoryAddVariable( &                          ! 変数定義
           varname='psi', dims=(/'x','y','t'/), & 
           longname='stream function', units='1', xtype='double')
      call HistoryAddVariable( &                          ! 変数定義
           varname='zeta', dims=(/'x','y','t'/), & 
           longname='voticity', units='1', xtype='double')
      call HistoryAddVariable( &                          ! 変数定義
           varname='temp', dims=(/'x','y','t'/), & 
           longname='temperature', units='1', xtype='double')

    end subroutine output_gtool4_init

    subroutine output_gtool4
      gg_temp = gg_et(et_temp)
      gg_psi  = gg_et(et_psi)
      gg_zeta = gg_et(et_zeta)

      write(6,*) 'it = ',it
      call HistoryPut('t',real(it*dt))
      call HistoryPut('psi',transpose(gg_psi))
      call HistoryPut('zeta',transpose(gg_zeta))
      call HistoryPut('temp',transpose(gg_temp))
    end subroutine output_gtool4

    subroutine output_gtool4_close
      call HistoryClose
    end subroutine output_gtool4_close

end program bsnconv
