!--
!----------------------------------------------------------------------
!     Copyright (c) 2019-2020 Shin-ichi Takehiro. All rights reserved.
!----------------------------------------------------------------------
!表題  ua_deriv_mpi_module_mint
!
!  spml/ua_deriv_mpi_module_mint モジュールは球面上での流体運動を
!  球面調和函数を用いたスペクトル法によって数値計算するための
!  モジュール ua_mpi_module_sypack の下部モジュールであり, スペクトル法の
!  微分計算のための Fortran90 関数を提供する.
!
!  球面上の 1 層モデル用 u_deriv_mpi_module_sypack モジュールを多層モデル用に
!  拡張したものであり, 同時に複数個のスペクトルデータ, 格子点データに
!  対する変換が行える.
!
!  内部で ISPACK3 の SYPACK の Fortran77 サブルーチンを呼んでいる.
!  スペクトルデータおよび格子点データの格納方法や変換の詳しい計算法に
!  ついては ISPACK3/SYPACK のマニュアルを参照されたい.
!
!履歴  2019/04/30  竹広真一
!      2020/08/05  竹広真一  xvb <=> pva と wb 関数を追加
!      2020/08/11  竹広真一  bug fixed
!
!      制限
!         ・変換する格子点データ, スペクトルデータの配列の大きさは決めうち
!
module ua_mpi_module_deriv_mint
  !
  != ua_mpi_module_deriv
  !
  ! Authors:: Shin-ichi Takehiro, Youhei SASAKI
  ! Version:: $Id$
  ! Copyright&License:: See COPYRIGHT[link:../COPYRIGHT]
  !
  !== 概要
  !
  !  spml/ua_mpi_module_deriv モジュールは球面上での流体運動を
  !  球面調和函数を用いたスペクトル法によって数値計算するための
  !  モジュール ua_mpi_module の下部モジュールであり, スペクトル法の
  !  微分計算のための Fortran90 関数を提供する.
  !
  !  球面上の 1 層モデル用 u_deriv_mpi_module モジュールを多層モデル用に
  !  拡張したものであり, 同時に複数個のスペクトルデータ, 格子点データに
  !  対する変換が行える.
  !
  !  内部で ISPACK3 の SYPACK の Fortran77 サブルーチンを呼んでいる.
  !  スペクトルデータおよび格子点データの格納方法や変換の詳しい計算法に
  !  ついては ISPACK3/SYPACK のマニュアルを参照されたい.
  !
  use dc_types, only: DP
  use dc_message, only : MessageNotify
  use w_mpi_module_base_mint, only : im, jm, nm=>nn, jc=>jl
  use w_mpi_module_deriv_mint
  use ua_mpi_module_base_mint, only : &
       & pva_ua, ua_pva, xvb_ua, ua_xvb, pva_wb, wb_pva, &
       & xv_u, u_xv, pv_w, w_pv, pv_u, u_pv, &
       & ic, nc, nmc, nms, nme, kc, km, ua_wb, wb_ua, ua_wa, wa_ua

  implicit none

  real(DP), allocatable  :: rnu(:,:)
  ! ラプラシアン演算用配列(u_module と互換性を保つため)
  !
  ! スペクトルデータのラプラシアンを計算するための係数
  ! 配列のサイズは(nmc, 2)
  !
  ! r(L,1) には L 番目の格納位置のスペクトルに対するラプラシアン計算の
  ! 係数 -n(n+1) の値が格納されている.

  ! private im, jm, nm, nc, kc                  ! for Intel Fortran
  private

  public ua_deriv_mpi_Initial
  public ua_deriv_mpi_Finalize

  public ua_Lapla_ua, ua_LaplaInv_ua          ! ラプラシアンと逆演算
  public ua_DLon_ua                           ! 経度微分
  public pva_GradLon_ua, pva_GradLat_ua       ! 勾配型微分
  public xvb_GradLon_ua, xvb_GradLat_ua       ! 勾配型微分
  public ua_DivLon_pva, ua_DivLat_pva         ! 発散型微分
  public ua_DivLon_xvb, ua_DivLat_xvb         ! 発散型微分
  public ua_Div_pva_pva                       ! 発散型微分
  public ua_Div_xvb_xvb                       ! 発散型微分
  public ua_JacobianMPI_ua_ua                 ! ヤコビアン
  public pva_GradLambda_ua, pva_GradMu_ua     ! 勾配型微分(λ,μ座標)
  public xvb_GradLambda_ua, xvb_GradMu_ua     ! 勾配型微分(λ,μ座標)
  public ua_DivLambda_pva, ua_DivMu_pva       ! 発散型微分(λ,μ座標)
  public ua_DivLambda_xvb, ua_DivMu_xvb       ! 発散型微分(λ,μ座標)

  public wb_Lapla_wb, wb_LaplaInv_wb          ! ラプラシアンと逆演算
  public wb_DLon_wb                           ! 経度微分
  public pva_GradLon_wb, pva_GradLat_wb       ! 勾配型微分
  public wb_DivLon_pva, wb_DivLat_pva         ! 発散型微分
  public wb_Div_pva_pva                       ! 発散型微分
  public wb_JacobianMPI_wb_wb                 ! ヤコビアン
  public pva_GradLambda_wb, pva_GradMu_wb     ! 勾配型微分(λ,μ座標)
  public wb_DivLambda_pva, wb_DivMu_pva       ! 発散型微分(λ,μ座標)

  public u_Lapla_u, u_LaplaInv_u              ! ラプラシアンと逆演算
  public u_DLon_u                             ! 経度微分
  public pv_GradLon_u, pv_GradLat_u           ! 勾配型微分
  public xv_GradLon_u, xv_GradLat_u           ! 勾配型微分
  public u_DivLon_pv, u_DivLat_pv             ! 発散型微分
  public u_DivLon_xv, u_DivLat_xv             ! 発散型微分
  public u_Div_pv_pv                          ! 発散型微分
  public u_Div_xv_xv                          ! 発散型微分  
  public u_JacobianMPI_u_u                    ! ヤコビアン
  public pv_GradLambda_u, pv_GradMu_u         ! 勾配型微分(λ,μ座標)
  public xv_GradLambda_u, xv_GradMu_u         ! 勾配型微分(λ,μ座標)
  public u_DivLambda_pv, u_DivMu_pv           ! 発散型微分(λ,μ座標)
  public u_DivLambda_xv, u_DivMu_xv           ! 発散型微分(λ,μ座標)

  public w_Lapla_w, w_LaplaInv_w              ! ラプラシアンと逆演算
  public w_DLon_w                             ! 経度微分
  public pv_GradLon_w, pv_GradLat_w           ! 勾配型微分
  public w_DivLon_pv, w_DivLat_pv             ! 発散型微分
  public w_Div_pv_pv                          ! 発散型微分
  public w_JacobianMPI_w_w                    ! ヤコビアン
  public pv_GradLambda_w, pv_GradMu_w         ! 勾配型微分(λ,μ座標)
  public w_DivLambda_pv, w_DivMu_pv           ! 発散型微分(λ,μ座標)
  
  public rn, rnu                              ! ラプラシアン演算用配列

contains

    !--------------- 初期化 -----------------
    subroutine ua_deriv_mpi_initial
      !
      ! スペクトル微分計算に必要となる作業領域を設定する.
      !
      ! 他の関数を呼ぶ前に, 最初にこのサブルーチンを呼んで
      ! 初期設定をしなければならない.
      !
      ! 上位サブルーチン ua_mpi_Initial を使用すること.
      !

      call w_deriv_mpi_initial

      allocate(rnu(nmc,2))                    ! ラプラシアン演算用配列
      rnu = rn(nms:nme,:)

      call MessageNotify('M','ua_deriv_mpi_initial', &
           'ua_mpi_module_deriv_mint (2020/08/11) is initialized')

    end subroutine ua_deriv_mpi_initial

    !--------------- 微分計算(ua, 多層) -----------------
    function ua_Lapla_ua(ua_data)
      !
      ! 入力スペクトルデータにラプラシアン
      !
      !    ▽^2 = 1/cos^2φ・∂^2/∂λ^2 + 1/cosφ・∂/∂φ(cosφ∂/∂φ)
      !
      ! を作用する(多層用).
      !
      ! スペクトルデータのラプラシアンとは, 対応する格子点データに
      ! ラプラシアンを作用させたデータのスペクトル変換のことである.
      !
      real(DP), intent(in)  :: ua_data(:,:)
      !(in) 入力スペクトルデータ
      real(DP)              :: ua_lapla_ua(nmc,size(ua_data,2))
      !(out) 入力スペクトルデータのラプラシアン
      integer :: k

      do k=1,size(ua_data,2)
         ua_Lapla_ua(:,k) = rnu(:,1)*ua_data(:,k)
      enddo

    end function ua_Lapla_ua

    function ua_LaplaInv_ua(ua_data)
      !
      ! 入力スペクトルデータに逆ラプラシアン
      !
      !    ▽^{-2}
      !      =[1/cos^2φ・∂^2/∂λ^2 + 1/cosφ・∂/∂φ(cosφ∂/∂φ)]^{-1}
      !
      ! を作用する(多層用).
      !
      ! スペクトルデータの逆ラプラシアンとは, 対応する格子点データに
      ! 逆ラプラシアンを作用させたデータのスペクトル変換のことである.
      !
      real(DP), intent(in)  :: ua_data(:,:)
      !(in) 入力スペクトルデータ
      real(DP)              :: ua_LaplaInv_ua(nmc,size(ua_data,2))
      !(out) スペクトルデータの逆ラプラシアン
      integer :: k

      do k=1,size(ua_data,2)
         ua_LaplaInv_ua(:,k) = rnu(:,2)*ua_data(:,k)
      enddo

    end function ua_LaplaInv_ua

    function ua_DLon_ua(ua_data)
      !
      ! スペクトルデータに経度微分 ∂/∂λ を作用させる(多層用).
      !
      ! スペクトルデータの経度微分とは, 対応する格子点データに
      ! 経度微分∂/∂λを作用させたデータのスペクトル変換のことである.
      !
      real(DP), intent(in)  :: ua_data(:,:)
      !(in) 入力スペクトルデータ
      real(DP)              :: ua_DLon_ua(nmc,size(ua_data,2))
      !(out) スペクトルデータの経度微分
      integer :: k

      real(DP) :: wb_data(nc,kc)

      wb_data = wb_ua(ua_data)
      do k=1,kc
         wb_data(:,k) = w_DLon_w(wb_data(:,k))
      enddo
      ua_DLon_ua = ua_wb(wb_data)

    end function ua_DLon_ua

    function pva_GradLon_ua(ua_data)
      !
      ! スペクトルデータに勾配型経度微分 1/cosφ・∂/∂λ を
      ! 作用させた格子点データを返す(多層用).
      !
      real(DP), intent(in)  :: ua_data(nmc,km)
      !(in) 入力スペクトルデータ
      real(DP)              :: pva_GradLon_ua(0:ic-1,jc,km)
      !(out) スペクトルデータを勾配型経度微分した格子点データ

      pva_GradLon_ua = pva_ua(ua_data,ipow=1,iflag=-1)

    end function pva_GradLon_ua

    function xvb_GradLon_ua(ua_data)
      !
      ! スペクトルデータに勾配型経度微分 1/cosφ・∂/∂λ を
      ! 作用させた格子点データを返す(多層用).
      !
      real(DP), intent(in)  :: ua_data(nmc,km)
      !(in) 入力スペクトルデータ
      real(DP)              :: xvb_GradLon_ua(0:im-1,jc,kc)
      !(out) スペクトルデータを勾配型経度微分した格子点データ

      xvb_GradLon_ua = xvb_ua(ua_data,ipow=1,iflag=-1)

    end function xvb_GradLon_ua

    function pva_GradLat_ua(ua_data)
      !
      ! スペクトルデータに勾配型緯度微分 ∂/∂φ を作用させて
      ! 格子点データに変換して返す(多層用).
      !
      real(DP), intent(in)  :: ua_data(nmc,km)
      !(in) 入力スペクトルデータ
      real(DP)              :: pva_GradLat_ua(0:ic-1,jc,km)
      !(out) スペクトルデータを勾配型緯度微分した格子点データ

      pva_GradLat_ua = pva_ua(ua_data,ipow=1,iflag=1)

    end function pva_GradLat_ua

    function xvb_GradLat_ua(ua_data)
      !
      ! スペクトルデータに勾配型緯度微分 ∂/∂φ を作用させて
      ! 格子点データに変換して返す(多層用).
      !
      real(DP), intent(in)  :: ua_data(nmc,km)
      !(in) 入力スペクトルデータ
      real(DP)              :: xvb_GradLat_ua(0:im-1,jc,kc)
      !(out) スペクトルデータを勾配型緯度微分した格子点データ

      xvb_GradLat_ua = xvb_ua(ua_data,ipow=1,iflag=1)

    end function xvb_GradLat_ua

    function ua_DivLon_pva(pva_data)
      !
      ! 格子点データに発散型経度微分 1/cosφ・∂/∂λ を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pva_data(0:ic-1,jc,kc)
      !(in) 入力格子点データ
      real(DP)              :: ua_DivLon_pva(nmc,km)
      !(out) 格子点データを発散型経度微分したスペクトルデータ

      ua_DivLon_pva = ua_pva(pva_data,ipow=1,iflag=-1)

    end function ua_DivLon_pva
    
    function ua_DivLon_xvb(xvb_data)
      !
      ! 格子点データに発散型経度微分 1/cosφ・∂/∂λ を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: xvb_data(0:im-1,jc,kc)
      !(in) 入力格子点データ
      real(DP)              :: ua_DivLon_xvb(nmc,km)
      !(out) 格子点データを発散型経度微分したスペクトルデータ

      ua_DivLon_xvb = ua_xvb(xvb_data,ipow=1,iflag=-1)

    end function ua_DivLon_xvb
    
    function ua_DivLat_pva(pva_data)
      !
      ! 格子点データに発散型緯度微分 1/cosφ・∂(f cosφ)/∂φ を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pva_data(0:ic-1,jc,kc)
      !(in) 入力格子点データ
      real(DP)              :: ua_DivLat_pva(nmc,km)
      !(out) 格子点データを発散型緯度微分したスペクトルデータ

      ua_DivLat_pva = ua_pva(pva_data,ipow=1,iflag=1)

    end function ua_DivLat_pva

    function ua_DivLat_xvb(xvb_data)
      !
      ! 格子点データに発散型緯度微分 1/cosφ・∂(f cosφ)/∂φ を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: xvb_data(0:im-1,jc,kc)
      !(in) 入力格子点データ
      real(DP)              :: ua_DivLat_xvb(nmc,km)
      !(out) 格子点データを発散型緯度微分したスペクトルデータ

      ua_DivLat_xvb = ua_xvb(xvb_data,ipow=1,iflag=1)

    end function ua_DivLat_xvb

    function ua_Div_pva_pva(pva_u,pva_v)
      !
      ! 2 つの入力格子点データをベクトル成分とする発散を計算し,
      ! スペクトルデータとして返す(多層用).
      !
      real(DP), intent(in)  :: pva_u(0:ic-1,jc,kc)
      !(in) ベクトル経度成分の格子点データ
      real(DP), intent(in)  :: pva_v(0:ic-1,jc,kc)
      !(in) ベクトル緯度成分の格子点データ
      real(DP)              :: ua_Div_pva_pva(nmc,km)
      !(out) 2 つの入力格子点データをベクトル成分とする発散のスペクトルデータ

      ua_Div_pva_pva = ua_DivLon_pva(pva_u) + ua_DivLat_pva(pva_v)

    end function ua_Div_pva_pva

    function ua_Div_xvb_xvb(xvb_u,xvb_v)
      !
      ! 2 つの入力格子点データをベクトル成分とする発散を計算し,
      ! スペクトルデータとして返す(多層用).
      !
      real(DP), intent(in)  :: xvb_u(0:im-1,jc,kc)
      !(in) ベクトル経度成分の格子点データ
      real(DP), intent(in)  :: xvb_v(0:im-1,jc,kc)
      !(in) ベクトル緯度成分の格子点データ
      real(DP)              :: ua_Div_xvb_xvb(nmc,km)
      !(out) 2 つの入力格子点データをベクトル成分とする発散のスペクトルデータ

      ua_Div_xvb_xvb = ua_DivLon_xvb(xvb_u) + ua_DivLat_xvb(xvb_v)

    end function ua_Div_xvb_xvb

    function ua_JacobianMPI_ua_ua(ua_a,ua_b)
      ! 2 つのスペクトルデータにヤコビアン
      !
      !   J(f,g) = ∂f/∂λ・∂g/∂μ - ∂g/∂λ・∂f/∂μ
      !          = ∂f/∂λ・1/cosφ・∂g/∂φ
      !             - ∂g/∂λ・1/cosφ・∂f/∂φ
      !
      ! を作用させる(多層用).
      !
      real(DP), intent(in) :: ua_a(nmc,km)
      !(in) 1つ目の入力スペクトルデータ
      real(DP), intent(in) :: ua_b(nmc,km)
      !(in) 2つ目の入力スペクトルデータ
      real(DP)             :: ua_JacobianMPI_ua_ua(nmc,km)
      !(out) 2 つのスペクトルデータのヤコビアン
      integer :: k

      real(DP) :: wb_a(nc,kc)
      real(DP) :: wb_b(nc,kc)

      wb_a = wb_ua(ua_a) ; wb_b = wb_ua(ua_b)

      do k=1,kc
         wb_a(:,k) = w_JacobianMPI_w_w(wb_a(:,k),wb_b(:,k))
      end do

      ua_JacobianMPI_ua_ua = ua_wb(wb_a)

    end function ua_JacobianMPI_ua_ua

    !--------------- 微分計算(wb 多層) -----------------
    function wb_Lapla_wb(wb_data)
      !
      ! 入力スペクトルデータにラプラシアン
      !
      !    ▽^2 = 1/cos^2φ・∂^2/∂λ^2 + 1/cosφ・∂/∂φ(cosφ∂/∂φ)
      !
      ! を作用する(多層用).
      !
      ! スペクトルデータのラプラシアンとは, 対応する格子点データに
      ! ラプラシアンを作用させたデータのスペクトル変換のことである.
      !
      real(DP), intent(in)  :: wb_data(:,:)
      !(in) 入力スペクトルデータ
      real(DP)              :: wb_lapla_wb(nc,size(wb_data,2))
      !(out) 入力スペクトルデータのラプラシアン
      integer :: k

      do k=1,size(wb_data,2)
         wb_Lapla_wb(:,k) = rn(:,1)*wb_data(:,k)
      enddo

    end function wb_Lapla_wb

    function wb_LaplaInv_wb(wb_data)
      !
      ! 入力スペクトルデータに逆ラプラシアン
      !
      !    ▽^{-2}
      !      =[1/cos^2φ・∂^2/∂λ^2 + 1/cosφ・∂/∂φ(cosφ∂/∂φ)]^{-1}
      !
      ! を作用する(多層用).
      !
      ! スペクトルデータの逆ラプラシアンとは, 対応する格子点データに
      ! 逆ラプラシアンを作用させたデータのスペクトル変換のことである.
      !
      real(DP), intent(in)  :: wb_data(:,:)
      !(in) 入力スペクトルデータ
      real(DP)              :: wb_LaplaInv_wb(nc,size(wb_data,2))
      !(out) スペクトルデータの逆ラプラシアン
      integer :: k

      do k=1,size(wb_data,2)
         wb_LaplaInv_wb(:,k) = rn(:,2)*wb_data(:,k)
      enddo

    end function wb_LaplaInv_wb

    function wb_DLon_wb(wb_data)
      !
      ! スペクトルデータに経度微分 ∂/∂λ を作用させる(多層用).
      !
      ! スペクトルデータの経度微分とは, 対応する格子点データに
      ! 経度微分∂/∂λを作用させたデータのスペクトル変換のことである.
      !
      real(DP), intent(in)  :: wb_data(:,:)
      !(in) 入力スペクトルデータ
      real(DP)              :: wb_DLon_wb(nc,size(wb_data,2))
      !(out) スペクトルデータの経度微分
      integer :: k

      do k=1,kc
         wb_DLon_wb(:,k) = w_DLon_w(wb_data(:,k))
      enddo

    end function wb_DLon_wb

    function pva_GradLon_wb(wb_data)
      !
      ! スペクトルデータに勾配型経度微分 1/cosφ・∂/∂λ を
      ! 作用させた格子点データを返す(多層用).
      !
      real(DP), intent(in)  :: wb_data(nc,kc)
      !(in) 入力スペクトルデータ
      real(DP)              :: pva_GradLon_wb(0:ic-1,jc,km)
      !(out) スペクトルデータを勾配型経度微分した格子点データ

      pva_GradLon_wb = pva_wb(wb_data,ipow=1,iflag=-1)

    end function pva_GradLon_wb

    function pva_GradLat_wb(wb_data)
      !
      ! スペクトルデータに勾配型緯度微分 ∂/∂φ を作用させて
      ! 格子点データに変換して返す(多層用).
      !
      real(DP), intent(in)  :: wb_data(nc,kc)
      !(in) 入力スペクトルデータ
      real(DP)              :: pva_GradLat_wb(0:ic-1,jc,km)
      !(out) スペクトルデータを勾配型緯度微分した格子点データ

      pva_GradLat_wb = pva_wb(wb_data,ipow=1,iflag=1)

    end function pva_GradLat_wb

    function wb_DivLon_pva(pva_data)
      !
      ! 格子点データに発散型経度微分 1/cosφ・∂/∂λ を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pva_data(0:ic-1,jc,km)
      !(in) 入力格子点データ
      real(DP)              :: wb_DivLon_pva(nc,kc)
      !(out) 格子点データを発散型経度微分したスペクトルデータ

      wb_DivLon_pva = wb_pva(pva_data,ipow=1,iflag=-1)

    end function wb_DivLon_pva

    function wb_DivLat_pva(pva_data)
      !
      ! 格子点データに発散型緯度微分 1/cosφ・∂(f cosφ)/∂φ を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pva_data(0:ic-1,jc,km)
      !(in) 入力格子点データ
      real(DP)              :: wb_DivLat_pva(nc,kc)
      !(out) 格子点データを発散型緯度微分したスペクトルデータ

      wb_DivLat_pva = wb_pva(pva_data,ipow=1,iflag=1)

    end function wb_DivLat_pva

    function wb_Div_pva_pva(pva_u,pva_v)
      !
      ! 2 つの入力格子点データをベクトル成分とする発散を計算し,
      ! スペクトルデータとして返す(多層用).
      !
      real(DP), intent(in)  :: pva_u(0:ic-1,jc,km)
      !(in) ベクトル経度成分の格子点データ
      real(DP), intent(in)  :: pva_v(0:ic-1,jc,km)
      !(in) ベクトル緯度成分の格子点データ
      real(DP)              :: wb_Div_pva_pva(nc,kc)
      !(out) 2 つの入力格子点データをベクトル成分とする発散のスペクトルデータ

      wb_Div_pva_pva = wb_DivLon_pva(pva_u) + wb_DivLat_pva(pva_v)

    end function wb_Div_pva_pva

    function wb_JacobianMPI_wb_wb(wb_a,wb_b)
      ! 2 つのスペクトルデータにヤコビアン
      !
      !   J(f,g) = ∂f/∂λ・∂g/∂μ - ∂g/∂λ・∂f/∂μ
      !          = ∂f/∂λ・1/cosφ・∂g/∂φ
      !             - ∂g/∂λ・1/cosφ・∂f/∂φ
      !
      ! を作用させる(多層用).
      !
      real(DP), intent(in) :: wb_a(nc,kc)
      !(in) 1つ目の入力スペクトルデータ
      real(DP), intent(in) :: wb_b(nc,kc)
      !(in) 2つ目の入力スペクトルデータ
      real(DP)             :: wb_JacobianMPI_wb_wb(nc,kc)
      !(out) 2 つのスペクトルデータのヤコビアン
      integer :: k

      do k=1,kc
         wb_JacobianMPI_wb_wb(:,k) = w_JacobianMPI_w_w(wb_a(:,k),wb_b(:,k))
      end do

    end function wb_JacobianMPI_wb_wb

    !--------------- 微分計算(u 一層) -----------------
    function u_Lapla_u(u_data)
      !
      ! 入力スペクトルデータにラプラシアン
      !
      !    ▽^2 = 1/cos^2φ・∂^2/∂λ^2 + 1/cosφ・∂/∂φ(cosφ∂/∂φ)
      !
      ! を作用する(多層用).
      !
      ! スペクトルデータのラプラシアンとは, 対応する格子点データに
      ! ラプラシアンを作用させたデータのスペクトル変換のことである.
      !
      real(DP), intent(in)  :: u_data(:)
      !(in) 入力スペクトルデータ
      real(DP)              :: u_lapla_u(nmc)
      !(out) 入力スペクトルデータのラプラシアン

      u_Lapla_u = rnu(:,1)*u_data

    end function u_Lapla_u

    function u_LaplaInv_u(u_data)
      !
      ! 入力スペクトルデータに逆ラプラシアン
      !
      !    ▽^{-2}
      !      =[1/cos^2φ・∂^2/∂λ^2 + 1/cosφ・∂/∂φ(cosφ∂/∂φ)]^{-1}
      !
      ! を作用する(多層用).
      !
      ! スペクトルデータの逆ラプラシアンとは, 対応する格子点データに
      ! 逆ラプラシアンを作用させたデータのスペクトル変換のことである.
      !
      real(DP), intent(in)  :: u_data(:)
      !(in) 入力スペクトルデータ
      real(DP)              :: u_LaplaInv_u(nmc)
      !(out) スペクトルデータの逆ラプラシアン

      u_LaplaInv_u = rnu(:,2)*u_data

    end function u_LaplaInv_u

    function u_DLon_u(u_data)
      !
      ! スペクトルデータに経度微分 ∂/∂λ を作用させる(多層用).
      !
      ! スペクトルデータの経度微分とは, 対応する格子点データに
      ! 経度微分∂/∂λを作用させたデータのスペクトル変換のことである.
      !
      real(DP), intent(in)  :: u_data(:)
      !(in) 入力スペクトルデータ
      real(DP)              :: u_DLon_u(nmc)
      !(out) スペクトルデータの経度微分

      real(DP) :: ua_data(nmc,1)

      ua_data(:,1) = u_data
      ua_data = ua_DLon_ua(ua_data)
      u_DLon_u = ua_data(:,1)

    end function u_DLon_u

    function pv_GradLon_u(u_data)
      !
      ! スペクトルデータに勾配型経度微分 1/cosφ・∂/∂λ を
      ! 作用させた格子点データを返す(多層用).
      !
      real(DP), intent(in)  :: u_data(nmc)
      !(in) 入力スペクトルデータ
      real(DP)              :: pv_GradLon_u(0:ic-1,jc)
      !(out) スペクトルデータを勾配型経度微分した格子点データ

      pv_GradLon_u = pv_u(u_data,ipow=1,iflag=-1)

    end function pv_GradLon_u

    function xv_GradLon_u(u_data)
      !
      ! スペクトルデータに勾配型経度微分 1/cosφ・∂/∂λ を
      ! 作用させた格子点データを返す(多層用).
      !
      real(DP), intent(in)  :: u_data(nmc)
      !(in) 入力スペクトルデータ
      real(DP)              :: xv_GradLon_u(0:im-1,jc)
      !(out) スペクトルデータを勾配型経度微分した格子点データ

      xv_GradLon_u = xv_u(u_data,ipow=1,iflag=-1)

    end function xv_GradLon_u

    function pv_GradLat_u(u_data)
      !
      ! スペクトルデータに勾配型緯度微分 ∂/∂φ を作用させて
      ! 格子点データに変換して返す(多層用).
      !
      real(DP), intent(in)  :: u_data(nmc)
      !(in) 入力スペクトルデータ
      real(DP)              :: pv_GradLat_u(0:ic-1,jc)
      !(out) スペクトルデータを勾配型緯度微分した格子点データ

      pv_GradLat_u = pv_u(u_data,ipow=1,iflag=1)

    end function pv_GradLat_u

    function xv_GradLat_u(u_data)
      !
      ! スペクトルデータに勾配型緯度微分 ∂/∂φ を作用させて
      ! 格子点データに変換して返す(多層用).
      !
      real(DP), intent(in)  :: u_data(nmc)
      !(in) 入力スペクトルデータ
      real(DP)              :: xv_GradLat_u(0:im-1,jc)
      !(out) スペクトルデータを勾配型緯度微分した格子点データ

      xv_GradLat_u = xv_u(u_data,ipow=1,iflag=1)

    end function xv_GradLat_u

    function u_DivLon_pv(pv_data)
      !
      ! 格子点データに発散型経度微分 1/cosφ・∂/∂λ を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pv_data(0:ic-1,jc)
      !(in) 入力格子点データ
      real(DP)              :: u_DivLon_pv(nmc)
      !(out) 格子点データを発散型経度微分したスペクトルデータ

      u_DivLon_pv = u_pv(pv_data,ipow=1,iflag=-1)

    end function u_DivLon_pv

    function u_DivLon_xv(xv_data)
      !
      ! 格子点データに発散型経度微分 1/cosφ・∂/∂λ を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: xv_data(0:im-1,jc)
      !(in) 入力格子点データ
      real(DP)              :: u_DivLon_xv(nmc)
      !(out) 格子点データを発散型経度微分したスペクトルデータ

      u_DivLon_xv = u_xv(xv_data,ipow=1,iflag=-1)

    end function u_DivLon_xv

    function u_DivLat_pv(pv_data)
      !
      ! 格子点データに発散型緯度微分 1/cosφ・∂(f cosφ)/∂φ を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pv_data(0:ic-1,jc)
      !(in) 入力格子点データ
      real(DP)              :: u_DivLat_pv(nmc)
      !(out) 格子点データを発散型緯度微分したスペクトルデータ

      u_DivLat_pv = u_pv(pv_data,ipow=1,iflag=1)

    end function u_DivLat_pv

    function u_DivLat_xv(xv_data)
      !
      ! 格子点データに発散型緯度微分 1/cosφ・∂(f cosφ)/∂φ を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: xv_data(0:im-1,jc)
      !(in) 入力格子点データ
      real(DP)              :: u_DivLat_xv(nmc)
      !(out) 格子点データを発散型緯度微分したスペクトルデータ

      u_DivLat_xv = u_xv(xv_data,ipow=1,iflag=1)

    end function u_DivLat_xv

    function u_Div_pv_pv(pv_Uvel,pv_Vvel)
      !
      ! 2 つの入力格子点データをベクトル成分とする発散を計算し,
      ! スペクトルデータとして返す(多層用).
      !
      real(DP), intent(in)  :: pv_Uvel(0:ic-1,jc)
      !(in) ベクトル経度成分の格子点データ
      real(DP), intent(in)  :: pv_Vvel(0:ic-1,jc)
      !(in) ベクトル緯度成分の格子点データ
      real(DP)              :: u_Div_pv_pv(nmc)
      !(out) 2 つの入力格子点データをベクトル成分とする発散のスペクトルデータ

      u_Div_pv_pv = u_DivLon_pv(pv_Uvel) + u_DivLat_pv(pv_Vvel)

    end function u_Div_pv_pv

    function u_Div_xv_xv(xv_Uvel,xv_Vvel)
      !
      ! 2 つの入力格子点データをベクトル成分とする発散を計算し,
      ! スペクトルデータとして返す(多層用).
      !
      real(DP), intent(in)  :: xv_Uvel(0:im-1,jc)
      !(in) ベクトル経度成分の格子点データ
      real(DP), intent(in)  :: xv_Vvel(0:im-1,jc)
      !(in) ベクトル緯度成分の格子点データ
      real(DP)              :: u_Div_xv_xv(nmc)
      !(out) 2 つの入力格子点データをベクトル成分とする発散のスペクトルデータ

      u_Div_xv_xv = u_DivLon_xv(xv_Uvel) + u_DivLat_xv(xv_Vvel)

    end function u_Div_xv_xv

    function u_JacobianMPI_u_u(u_a,u_b)
      ! 2 つのスペクトルデータにヤコビアン
      !
      !   J(f,g) = ∂f/∂λ・∂g/∂μ - ∂g/∂λ・∂f/∂μ
      !          = ∂f/∂λ・1/cosφ・∂g/∂φ
      !             - ∂g/∂λ・1/cosφ・∂f/∂φ
      !
      ! を作用させる(多層用).
      !
      real(DP), intent(in) :: u_a(nmc)
      !(in) 1つ目の入力スペクトルデータ
      real(DP), intent(in) :: u_b(nmc)
      !(in) 2つ目の入力スペクトルデータ
      real(DP)             :: u_JacobianMPI_u_u(nmc)
      !(out) 2 つのスペクトルデータのヤコビアン

      real(DP) :: ua_a(nmc,1)
      real(DP) :: ua_b(nmc,1)
      real(DP) :: wa_a(nc,1)
      real(DP) :: wa_b(nc,1)

      ua_a(:,1) = u_a ; ua_b(:,1) = u_b
      wa_a = wa_ua(ua_a) ; wa_b = wa_ua(ua_b)
      wa_a(:,1) = w_JacobianMPI_w_w(wa_a(:,1),wa_b(:,1))
      ua_a = ua_wa(wa_a)
      u_JacobianMPI_u_u = ua_a(:,1)

    end function u_JacobianMPI_u_u

    !--------------- 微分計算(u 一層) -----------------
    
    function pv_GradLon_w(w_data)
      !
      ! スペクトルデータに勾配型経度微分 1/cosφ・∂/∂λ を
      ! 作用させた格子点データを返す(多層用).
      !
      real(DP), intent(in)  :: w_data(nc)
      !(in) 入力スペクトルデータ
      real(DP)              :: pv_GradLon_w(0:ic-1,jc)
      !(out) スペクトルデータを勾配型経度微分した格子点データ

      pv_GradLon_w = pv_w(w_data,ipow=1,iflag=-1)

    end function pv_GradLon_w

    function pv_GradLat_w(w_data)
      !
      ! スペクトルデータに勾配型緯度微分 ∂/∂φ を作用させて
      ! 格子点データに変換して返す(多層用).
      !
      real(DP), intent(in)  :: w_data(nc)
      !(in) 入力スペクトルデータ
      real(DP)              :: pv_GradLat_w(0:ic-1,jc)
      !(out) スペクトルデータを勾配型緯度微分した格子点データ

      pv_GradLat_w = pv_w(w_data,ipow=1,iflag=1)

    end function pv_GradLat_w

    function w_DivLon_pv(pv_data)
      !
      ! 格子点データに発散型経度微分 1/cosφ・∂/∂λ を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pv_data(0:ic-1,jc)
      !(in) 入力格子点データ
      real(DP)              :: w_DivLon_pv(nc)
      !(out) 格子点データを発散型経度微分したスペクトルデータ

      w_DivLon_pv = w_pv(pv_data,ipow=1,iflag=-1)

    end function w_DivLon_pv

    function w_DivLat_pv(pv_data)
      !
      ! 格子点データに発散型緯度微分 1/cosφ・∂(f cosφ)/∂φ を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pv_data(0:ic-1,jc)
      !(in) 入力格子点データ
      real(DP)              :: w_DivLat_pv(nc)
      !(out) 格子点データを発散型緯度微分したスペクトルデータ

      w_DivLat_pv = w_pv(pv_data,ipow=1,iflag=1)

    end function w_DivLat_pv

    function w_Div_pv_pv(pv_u,pv_v)
      !
      ! 2 つの入力格子点データをベクトル成分とする発散を計算し,
      ! スペクトルデータとして返す(多層用).
      !
      real(DP), intent(in)  :: pv_u(0:ic-1,jc)
      !(in) ベクトル経度成分の格子点データ
      real(DP), intent(in)  :: pv_v(0:ic-1,jc)
      !(in) ベクトル緯度成分の格子点データ
      real(DP)              :: w_Div_pv_pv(nc)
      !(out) 2 つの入力格子点データをベクトル成分とする発散のスペクトルデータ

      w_Div_pv_pv = w_DivLon_pv(pv_u) + w_DivLat_pv(pv_v)

    end function w_Div_pv_pv

    !--------------- 微分計算 (λ,μ座標系用, ua 多層) -----------------
    function pva_GradLambda_ua(ua_data)
      !
      ! スペクトルデータに勾配型経度微分 ∂/∂λ を作用する(多層用).
      !
      real(DP), intent(in)  :: ua_data(nmc,km)
      !(in) 入力スペクトルデータ
      real(DP)              :: pva_GradLambda_ua(0:ic-1,jc,km)
      !(out) スペクトルデータを勾配型経度微分した格子点データ

      pva_GradLambda_ua = pva_ua(ua_data,ipow=0,iflag=-1)

    end function pva_GradLambda_ua

    function xvb_GradLambda_ua(ua_data)
      !
      ! スペクトルデータに勾配型経度微分 ∂/∂λ を作用する(多層用).
      !
      real(DP), intent(in)  :: ua_data(nmc,km)
      !(in) 入力スペクトルデータ
      real(DP)              :: xvb_GradLambda_ua(0:im-1,jc,kc)
      !(out) スペクトルデータを勾配型経度微分した格子点データ

      xvb_GradLambda_ua = xvb_ua(ua_data,ipow=0,iflag=-1)

    end function xvb_GradLambda_ua

    function pva_GradMu_ua(ua_data)
      !
      ! スペクトルデータに勾配型緯度微分 (1-μ^2)∂/∂μ  (μ=sinφ)
      ! を作用させて格子点データに変換して返す(多層用).
      !
      real(DP), intent(in)  :: ua_data(nmc,km)
      !(in) 入力スペクトルデータ
      real(DP)              :: pva_GradMu_ua(0:ic-1,jc,km)
      !(out) スペクトルデータを勾配型緯度微分した格子点データ

      pva_GradMu_ua = pva_ua(ua_data,ipow=0,iflag=1)

    end function pva_GradMu_ua

    function xvb_GradMu_ua(ua_data)
      !
      ! スペクトルデータに勾配型緯度微分 (1-μ^2)∂/∂μ  (μ=sinφ)
      ! を作用させて格子点データに変換して返す(多層用).
      !
      real(DP), intent(in)  :: ua_data(nmc,km)
      !(in) 入力スペクトルデータ
      real(DP)              :: xvb_GradMu_ua(0:im-1,jc,kc)
      !(out) スペクトルデータを勾配型緯度微分した格子点データ

      xvb_GradMu_ua = xvb_ua(ua_data,ipow=0,iflag=1)

    end function xvb_GradMu_ua

    function ua_DivLambda_pva(pva_data)
      !
      ! 格子点データに発散型経度微分 1/(1-μ^2)・∂/∂λ (μ=sinφ)
      ! を作用させてスペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pva_data(0:ic-1,jc,km)
      !(in) 入力格子点データ
      real(DP)              :: ua_DivLambda_pva(nmc,km)
      !(out) 格子点データを発散型経度微分したスペクトルデータ

      ua_DivLambda_pva = ua_pva(pva_data,ipow=2,iflag=-1)

    end function ua_DivLambda_pva

    function ua_DivLambda_xvb(xvb_data)
      !
      ! 格子点データに発散型経度微分 1/(1-μ^2)・∂/∂λ (μ=sinφ)
      ! を作用させてスペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: xvb_data(0:im-1,jc,kc)
      !(in) 入力格子点データ
      real(DP)              :: ua_DivLambda_xvb(nmc,km)
      !(out) 格子点データを発散型経度微分したスペクトルデータ

      ua_DivLambda_xvb = ua_xvb(xvb_data,ipow=2,iflag=-1)

    end function ua_DivLambda_xvb

    function ua_DivMu_pva(pva_data)
      !
      ! 格子点データに発散型緯度微分 ∂/∂μ (μ=sinφ)を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pva_data(0:ic-1,jc,km)
      !(in) 入力格子点データ
      real(DP)              :: ua_DivMu_pva(nmc,km)
      !(out) 格子点データを発散型緯度微分したスペクトルデータ

      ua_DivMu_pva = ua_pva(pva_data,ipow=2,iflag=1)

    end function ua_DivMu_pva

    function ua_DivMu_xvb(xvb_data)
      !
      ! 格子点データに発散型緯度微分 ∂/∂μ (μ=sinφ)を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: xvb_data(0:im-1,jc,kc)
      !(in) 入力格子点データ
      real(DP)              :: ua_DivMu_xvb(nmc,km)
      !(out) 格子点データを発散型緯度微分したスペクトルデータ

      ua_DivMu_xvb = ua_xvb(xvb_data,ipow=2,iflag=1)

    end function ua_DivMu_xvb

    !--------------- 微分計算 (λ,μ座標系用, wb 多層) -----------------
    function pva_GradLambda_wb(wb_data)
      !
      ! スペクトルデータに勾配型経度微分 ∂/∂λ を作用する(多層用).
      !
      real(DP), intent(in)  :: wb_data(nc,kc)
      !(in) 入力スペクトルデータ
      real(DP)              :: pva_GradLambda_wb(0:ic-1,jc,km)
      !(out) スペクトルデータを勾配型経度微分した格子点データ

      pva_GradLambda_wb = pva_wb(wb_data,ipow=0,iflag=-1)

    end function pva_GradLambda_wb

    function pva_GradMu_wb(wb_data)
      !
      ! スペクトルデータに勾配型緯度微分 (1-μ^2)∂/∂μ  (μ=sinφ)
      ! を作用させて格子点データに変換して返す(多層用).
      !
      real(DP), intent(in)  :: wb_data(nc,kc)
      !(in) 入力スペクトルデータ
      real(DP)              :: pva_GradMu_wb(0:ic-1,jc,km)
      !(out) スペクトルデータを勾配型緯度微分した格子点データ

      pva_GradMu_wb = pva_wb(wb_data,ipow=0,iflag=1)

    end function pva_GradMu_wb

    function wb_DivLambda_pva(pva_data)
      !
      ! 格子点データに発散型経度微分 1/(1-μ^2)・∂/∂λ (μ=sinφ)
      ! を作用させてスペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pva_data(0:ic-1,jc,km)
      !(in) 入力格子点データ
      real(DP)              :: wb_DivLambda_pva(nc,kc)
      !(out) 格子点データを発散型経度微分したスペクトルデータ

      wb_DivLambda_pva = wb_pva(pva_data,ipow=2,iflag=-1)

    end function wb_DivLambda_pva

    function wb_DivMu_pva(pva_data)
      !
      ! 格子点データに発散型緯度微分 ∂/∂μ (μ=sinφ)を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pva_data(0:ic-1,jc,km)
      !(in) 入力格子点データ
      real(DP)              :: wb_DivMu_pva(nc,kc)
      !(out) 格子点データを発散型緯度微分したスペクトルデータ

      wb_DivMu_pva = wb_pva(pva_data,ipow=2,iflag=1)

    end function wb_DivMu_pva

    !--------------- 微分計算 (λ,μ座標系用, u 一層) -----------------
    function pv_GradLambda_u(u_data)
      !
      ! スペクトルデータに勾配型経度微分 ∂/∂λ を作用する(多層用).
      !
      real(DP), intent(in)  :: u_data(nmc)
      !(in) 入力スペクトルデータ
      real(DP)              :: pv_GradLambda_u(0:ic-1,jc)
      !(out) スペクトルデータを勾配型経度微分した格子点データ

      pv_GradLambda_u = pv_u(u_data,ipow=0,iflag=-1)

    end function pv_GradLambda_u

    function xv_GradLambda_u(u_data)
      !
      ! スペクトルデータに勾配型経度微分 ∂/∂λ を作用する(多層用).
      !
      real(DP), intent(in)  :: u_data(nmc)
      !(in) 入力スペクトルデータ
      real(DP)              :: xv_GradLambda_u(0:im-1,jc)
      !(out) スペクトルデータを勾配型経度微分した格子点データ

      xv_GradLambda_u = xv_u(u_data,ipow=0,iflag=-1)

    end function xv_GradLambda_u

    function pv_GradMu_u(u_data)
      !
      ! スペクトルデータに勾配型緯度微分 (1-μ^2)∂/∂μ  (μ=sinφ)
      ! を作用させて格子点データに変換して返す(多層用).
      !
      real(DP), intent(in)  :: u_data(nmc)
      !(in) 入力スペクトルデータ
      real(DP)              :: pv_GradMu_u(0:ic-1,jc)
      !(out) スペクトルデータを勾配型緯度微分した格子点データ

      pv_GradMu_u = pv_u(u_data,ipow=0,iflag=1)

    end function pv_GradMu_u

    function xv_GradMu_u(u_data)
      !
      ! スペクトルデータに勾配型緯度微分 (1-μ^2)∂/∂μ  (μ=sinφ)
      ! を作用させて格子点データに変換して返す(多層用).
      !
      real(DP), intent(in)  :: u_data(nmc)
      !(in) 入力スペクトルデータ
      real(DP)              :: xv_GradMu_u(0:im-1,jc)
      !(out) スペクトルデータを勾配型緯度微分した格子点データ

      xv_GradMu_u = xv_u(u_data,ipow=0,iflag=1)

    end function xv_GradMu_u

    function u_DivLambda_pv(pv_data)
      !
      ! 格子点データに発散型経度微分 1/(1-μ^2)・∂/∂λ (μ=sinφ)
      ! を作用させてスペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pv_data(0:ic-1,jc)
      !(in) 入力格子点データ
      real(DP)              :: u_DivLambda_pv(nmc)
      !(out) 格子点データを発散型経度微分したスペクトルデータ

      u_DivLambda_pv = u_pv(pv_data,ipow=2,iflag=-1)

    end function u_DivLambda_pv

    function u_DivLambda_xv(xv_data)
      !
      ! 格子点データに発散型経度微分 1/(1-μ^2)・∂/∂λ (μ=sinφ)
      ! を作用させてスペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: xv_data(0:im-1,jc)
      !(in) 入力格子点データ
      real(DP)              :: u_DivLambda_xv(nmc)
      !(out) 格子点データを発散型経度微分したスペクトルデータ

      u_DivLambda_xv = u_xv(xv_data,ipow=2,iflag=-1)

    end function u_DivLambda_xv

    function u_DivMu_pv(pv_data)
      !
      ! 格子点データに発散型緯度微分 ∂/∂μ (μ=sinφ)を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pv_data(0:ic-1,jc)
      !(in) 入力格子点データ
      real(DP)              :: u_DivMu_pv(nmc)
      !(out) 格子点データを発散型緯度微分したスペクトルデータ

      u_DivMu_pv = u_pv(pv_data,ipow=2,iflag=1)

    end function u_DivMu_pv

    function u_DivMu_xv(xv_data)
      !
      ! 格子点データに発散型緯度微分 ∂/∂μ (μ=sinφ)を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: xv_data(0:im-1,jc)
      !(in) 入力格子点データ
      real(DP)              :: u_DivMu_xv(nmc)
      !(out) 格子点データを発散型緯度微分したスペクトルデータ

      u_DivMu_xv = u_xv(xv_data,ipow=2,iflag=1)

    end function u_DivMu_xv

    !--------------- 微分計算 (λ,μ座標系用, w 一層) -----------------
    function pv_GradLambda_w(w_data)
      !
      ! スペクトルデータに勾配型経度微分 ∂/∂λ を作用する(多層用).
      !
      real(DP), intent(in)  :: w_data(nc)
      !(in) 入力スペクトルデータ
      real(DP)              :: pv_GradLambda_w(0:ic-1,jc)
      !(out) スペクトルデータを勾配型経度微分した格子点データ

      pv_GradLambda_w = pv_w(w_data,ipow=0,iflag=-1)

    end function pv_GradLambda_w

    function pv_GradMu_w(w_data)
      !
      ! スペクトルデータに勾配型緯度微分 (1-μ^2)∂/∂μ  (μ=sinφ)
      ! を作用させて格子点データに変換して返す(多層用).
      !
      real(DP), intent(in)  :: w_data(nc)
      !(in) 入力スペクトルデータ
      real(DP)              :: pv_GradMu_w(0:ic-1,jc)
      !(out) スペクトルデータを勾配型緯度微分した格子点データ

      pv_GradMu_w = pv_w(w_data,ipow=0,iflag=1)

    end function pv_GradMu_w

    function w_DivLambda_pv(pv_data)
      !
      ! 格子点データに発散型経度微分 1/(1-μ^2)・∂/∂λ (μ=sinφ)
      ! を作用させてスペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pv_data(0:ic-1,jc)
      !(in) 入力格子点データ
      real(DP)              :: w_DivLambda_pv(nc)
      !(out) 格子点データを発散型経度微分したスペクトルデータ

      w_DivLambda_pv = w_pv(pv_data,ipow=2,iflag=-1)

    end function w_DivLambda_pv

    function w_DivMu_pv(pv_data)
      !
      ! 格子点データに発散型緯度微分 ∂/∂μ (μ=sinφ)を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(DP), intent(in)  :: pv_data(0:ic-1,jc)
      !(in) 入力格子点データ
      real(DP)              :: w_DivMu_pv(nc)
      !(out) 格子点データを発散型緯度微分したスペクトルデータ

      w_DivMu_pv = w_pv(pv_data,ipow=2,iflag=1)

    end function w_DivMu_pv

    !--------------- 終了処理 -----------------
    subroutine ua_deriv_mpi_Finalize
      !
      ! モジュールの終了処理(割り付け配列の解放)をおこなう.
      !

      deallocate(rnu)                    ! ラプラシアン演算用配列

      call w_deriv_mpi_Finalize

      call MessageNotify('M','ua_deriv_mpi_finalize',&
           'ua_mpi_module_deriv_mint is finalized (2020/01/25) ')

    end subroutine ua_deriv_mpi_Finalize

end module ua_mpi_module_deriv_mint
